Programação web

Esse "treco" do PAF-ECF e outras porcarias fiscais.

2011-08-20T06:53:00.000-07:00

Antes a gente ia nos foruns de programação pra discutir uma nova técnica, um aspecto obscuro da linguagem ou do framework de trabalho. Isso acabou faz tempo.

Hoje, na maioria dos foruns de programação do Brasil, principalmente os mais voltados a programação de aplicativos comerciais, só se fala de ECF, PAF-ECF, SPED, SEF, NFe e outras porcarias fiscais. Tem programador que sabe mais de legislação do que os contadores dos clientes.

Inventário ANVISA - Resolvendo problemas

2011-07-19T08:01:00.000-07:00

Encontrei problemas na recuperação do inventário da ANVISA. Principalmente quando na descrição da razão social da empresa tinha o caracter '&'. Debugando com o fiddler2, estava tudo correto, mas quando gravava o responseText, não ia de jeito nenhum.

A forma mais simples que usei foi trocar o responseText por responseXML na função LOGIN(...). Funcionou de primeira.

Pode ser que nas outras respostas, também tenha que mudar para responseXML. Mas não fiz os testes ainda.

API do Twitter

2011-06-25T06:17:00.000-07:00

Até o ano passado, o Twitter permitia que a autorização fosse realizada apenas com a chave usuário/senha. Mas isso mudou : agora, quase todas as requisições precisam de autorização OAuth, bem mais complicada, e me parece, sem uma lib do xHarbour para isso.
Tem alguns exemplos de lib em Java, C++ e Delphi, vou estudar e ver qual é mais fácil de converter para C para usar com xHarbour.

Testando API do Twitter

2011-06-24T10:30:00.000-07:00

Comecei alguns testes com a API do twitter. A primeira vista não parece nada complicado ou diferente do que já tinha feito para a ANVISA : Usar o objeto XMLHTTPRequest para realizar as chamadas e ler seu resultado. Vou postar um exemplo para testar se a comunicação entre o programa e o Twitter está funcionando.

Se retornar o status = 200, está tudo OK.

#include "inkey.ch"

***************
FUNCTION main()
***************
   local http

   setmode(25,80)
   wvw_settitle(,"Testando API do Twitter")
   setcolor( 'N/W,N/GR*,,,N/W*' )
   cls

   if !Configura(@http)
      Alert("Verifique o erro e tente outra vez.")
      quit
   endif

   Alert("Verificar Status Twitter")

   http:Open( "GET", "https://twitter.com/help/test.xml", .F. )
   http:send()

   nStatus := strzero( http:status,3 )

   Alert("Status = " + nStatus)
return NIL

*********************************
STATIC FUNCTION CONFIGURA( http )
*********************************
   local aHosts, cAddress := "www.google.com.br", lRet := .T.

   begin sequence
      InetInit()
      aHosts := InetGetHosts( cAddress )
      if aHosts == NIL .or. len(aHosts) == 0
         lRet := .F.
         break
      endif
      InetCleanup()

      try
         http := CreateObject( "MSXML2.XMLHTTP" )
      catch
         try
            http := CreateObject( "MSXML2.XMLHTTP" )
         catch
            Alert("Erro na criacao do objeto MSXML2.XMLHTTP : " + Ole2TxtError())
            lRet := .F.
         end
      end
   end sequence
RETURN lRet

Exemplo - Recuperando inventário da ANVISA/SNGPC

2011-06-15T08:23:00.000-07:00

Nesse último exemplo para o SNGPC, não uso nenhum webservice da ANVISA. Essa operação não é padrão. Significa que se mudarem a forma de acesso ou a sequencia do login, o programa poderá deixar de funcionar.

Como o programa exemplo ficou grande pra um blog (>500 linhas), achei melhor colocar no 4shared.

O programa é bem fácil de ler. Coloquei diversos comentários, até pra me lembrar do que tava fazendo, já que uso essa função no meu software de SNGPC.

Exemplo - Testando status do arquivo XML enviado

2011-06-14T19:58:00.000-07:00

Nesse terceiro exemplo, testamos o recebimento do arquivo XML ou podemos obter a relação de erros de validação e gerar um relatório de erros. A parte do exemplo que trata dos erros deve ser melhor estudada e/ou melhorada.

#define CR_LF chr(13) + chr(10)

***************
FUNCTION MAIN()
***************
   local lRet := .T.

   if !InternetOK()
      Alert("Sem conexão com a Internet. Verifique...")
      return .F.
   endif
   //
   // ABERTURA DAS FUNCOES PARA WEBSERVICE DO XHARBOUR - OBJETO HTTP
   //
   try
      http := CreateObject( "MSXML2.XMLHTTP" )
   catch
      try
         http := CreateObject( "MSXML2.XMLHTTP" )
      catch
         Alert("Erro na criação do objeto MSXML2.XMLHTTP : " + Ole2TxtError())
      end
   end
   //
   // CRIA OBJETO XML
   //
   try
      doc := CreateObject( "MSXML2.DOMDocument" )
   catch
      try
         doc := CreateObject( "MSXML2.DOMDocument" )
      catch
         Alert("Erro na criacao do objeto MSXML2.DOMDocument : " + Ole2TxtError())
         return .F.
      end
   end

   cXml := ""
   cXml += '<?xml version="1.0" encoding="ISO-8859-1" ?>' + CR_LF
   cXml += '<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:tem="http://tempuri.org/">' + CR_LF
   cXml += '  <soapenv:Header/>' + CR_LF
   cXml += '  <soapenv:Body>' + CR_LF
   cXml += '    <tem:ConsultaDadosArquivoSNGPC>' + CR_LF
   cXml += '      <tem:Email>' + SEU_EMAIL_AQUI + '</tem:Email>' + CR_LF
   cXml += '      <tem:Senha>' + SUA_SENHA_AQUI + '</tem:Senha>' + CR_LF
   cXml += '      <tem:CNPJ>' + CNPJ_DA_EMPRESA + '</tem:CNPJ>' + CR_LF
   cXml += '      <tem:Hash>' + HASH_DO_ARQUIVO + '</tem:Hash>' + CR_LF
   cXml += '    </tem:ConsultaDadosArquivoSNGPC>' + CR_LF
   cXml += '  </soapenv:Body> ' + CR_LF
   cXml += '</soapenv:Envelope>' + CR_LF

//
// ENDERECO HOMOLOGACAO
//
   http:Open( "POST", "http://homologacao.anvisa.gov.br/sngpc/webservice/sngpc.asmx?WSDL HTTP/1.1", .F. )
   http:SetRequestHeader( "Content-Type"   , "text/xml;charset=ISO-8859-1" )
   http:SetRequestHeader( "SOAPAction"     , "http://tempuri.org/ConsultaDadosArquivoSNGPC" )
   http:SetRequestHeader( "Host"           , "homologacao.anvisa.gov.br" )

//
// ENDERECO PRODUCAO
//
// http:Open( "POST", "http://sngpc.anvisa.gov.br/webservice/sngpc.asmx?WSDL HTTP/1.1", .F. )
// http:SetRequestHeader( "Content-Type"   , "text/xml;charset=ISO-8859-1" )
// http:SetRequestHeader( "SOAPAction"     , "http://tempuri.org/ConsultaDadosArquivoSNGPC" )
// http:SetRequestHeader( "Host"           , "sngpc.anvisa.gov.br" )

   doc:LoadXML( cXml )
   http:send( doc:xml )
   response  := http:responseText
   oXmlDoc   := TXmlDocument():new()
   oXMlDoc:read( response )

   oXmlNode := oXmlDoc:findFirst( "ConsultaDadosArquivoSNGPCResult" )
   cDados   := oXmlNode:cData

   oXMlDoc:read( cDados )

   oXmlNode := oXmlDoc:findFirst( "DATAVALIDACAO" )

   if oXmlNode == NIL .or. oXmlNode:cData == NIL .or. empty( oXmlNode:cData )
      Alert("Arquivo ainda nao foi validado...")
      lRet := .F.
   else
      cMens    := oXmlNode:cData
      oXmlNode := oXmlDoc:findFirst( "MENSAGEMVALIDACAO" )
      if oXmlNode == NIL
         Alert("Arquivo validado em : " + cMens )
      else
         nHandle := fcreate( "temp.txt" )
         fwrite( nHandle, oXmlNode:cData )
         fclose( nHandle )
         nHandle := fopen( "temp.txt" )
         aLinhas := {}
         cLinha  := ""

         while HB_FReadLine( nHandle, @cLinha, "[NOVA_LINHA]" ) == 0
            aadd( aLinhas, cLinha )
         enddo
         aadd( aLinhas, cLinha )
         fclose( nHandle )

         if Alert("Arquivo enviado n„o foi recebido. Emite relat¢rio com erros ?", { "SIM", "NAO" } ) == 1
            // IMPRIME RELATORIO COM ERROS DE VALIDACAO DO XML
         endif
         lRet := .F.
      endif
   endif
RETURN lRet

*********************
FUNCTION InternetOK()
*********************
   local aHosts, cName, cAddress := "www.google.com.br"
   InetInit()
   aHosts := InetGetHosts( cAddress )
   if aHosts == NIL .or. len(aHosts) == 0
      InetCleanup()
      return .F.
   endif
   InetCleanup()
RETURN .T.

Exemplo - Enviando arquivo XML

2011-06-14T16:29:00.000-07:00

Nesse segundo exemplo, vamos enviar o arquivo XML para ANVISA. Note que no XML as tags < e > devem ser trocadas por & l t ; e & g t ;.
Claro que esse hash calculado deve ser gravado em algum lugar para depois testar se o arquivo foi recebido, se está com erros, etc. Vamos ver o uso desse código no próximo exemplo.

#define CR_LF chr(13) + chr(10)

***************
FUNCTION MAIN()
***************
   if !InternetOK()
      Alert("Sem conexão com a Internet. Verifique...")
      return .F.
   endif
   //
   // ABERTURA DAS FUNCOES PARA WEBSERVICE DO XHARBOUR - OBJETO HTTP
   //
   try
      http := CreateObject( "MSXML2.XMLHTTP" )
   catch
      try
         http := CreateObject( "MSXML2.XMLHTTP" )
      catch
         Alert("Erro na criação do objeto MSXML2.XMLHTTP : " + Ole2TxtError())
      end
   end
   //
   // CRIA OBJETO XML
   //
   try
      doc := CreateObject( "MSXML2.DOMDocument" )
   catch
      try
         doc := CreateObject( "MSXML2.DOMDocument" )
      catch
         Alert("Erro na criacao do objeto MSXML2.DOMDocument : " + Ole2TxtError())
         return NIL
      end
   end

   cFile := memoread( seu_arquivo_xml )
   cHash := HB_MD5File( seu_arquivo_xml )

   cXml := ""
   cXml += '<?xml version="1.0" encoding="ISO-8859-1" ?>' + CR_LF
   cXml += '<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:tem="http://tempuri.org/">' + CR_LF
   cXml += '  <soapenv:Header/>' + CR_LF
   cXml += '  <soapenv:Body>' + CR_LF
   cXml += '    <tem:EnviaArquivoSNGPC>' + CR_LF
   cXml += '      <tem:Email>' + SEU_EMAIL_AQUI + '</tem:Email>' + CR_LF
   cXml += '      <tem:Senha>' + SUA_SENHA_AQUI + '</tem:Senha>' + CR_LF
   cXml += '      <tem:Arquivo>' + cFile + '</tem:Arquivo>' + CR_LF
   cXml += '      <tem:HashIdentificacao>' + cHash + '</tem:HashIdentificacao>' + CR_LF
   cXml += '    </tem:EnviaArquivoSNGPC>' + CR_LF
   cXml += '  </soapenv:Body> ' + CR_LF
   cXml += '</soapenv:Envelope>' + CR_LF

//
// ENDERECO HOMOLOGACAO
//
   http:Open( "POST", "http://homologacao.anvisa.gov.br/sngpc/webservice/sngpc.asmx?WSDL HTTP/1.1", .F. )
   http:SetRequestHeader( "Content-Type"   , "text/xml;charset=ISO-8859-1" )
   http:SetRequestHeader( "SOAPAction"     , "http://tempuri.org/EnviaArquivoSNGPC" )
   http:SetRequestHeader( "Host"           , "homologacao.anvisa.gov.br" )

//
// ENDERECO PRODUCAO
//
// http:Open( "POST", "http://sngpc.anvisa.gov.br/webservice/sngpc.asmx?WSDL HTTP/1.1", .F. )
// http:SetRequestHeader( "Content-Type"   , "text/xml;charset=ISO-8859-1" )
// http:SetRequestHeader( "SOAPAction"     , "http://tempuri.org/EnviaArquivoSNGPC" )
// http:SetRequestHeader( "Host"           , "sngpc.anvisa.gov.br" )

   doc:LoadXML( cXml )
   http:send( doc:xml )
   response  := http:responseText
   oXmlDoc   := TXmlDocument():new()
   oXMlDoc:read( response )

   oXmlNode := oXmlDoc:findFirst( "EnviaArquivoSNGPCResult" )
   if empty( oXmlNode:cData )
      Alert("Erro no envio do arquivo para ANVISA. Tente outra vez.")
   elseif upper( left( oXmlNode:cData, 28 ) ) == "ARQUIVO RECEBIDO COM SUCESSO"
      Alert(oXmlNode:cData)
   else
      Alert(oXmlNode:cData)
      Alert("Erro no envio do arquivo para ANVISA. Tente outra vez.")
   endif
RETURN NIL

*********************
FUNCTION InternetOK()
*********************
   local aHosts, cName, cAddress := "www.google.com.br"
   InetInit()
   aHosts := InetGetHosts( cAddress )
   if aHosts == NIL .or. len(aHosts) == 0
      InetCleanup()
      return .F.
   endif
   InetCleanup()
RETURN .T.

Exemplo - Validando Usuário

2011-06-14T08:09:00.000-07:00

Estou usando o seguinte código para validar o usuário/senha :

#define CR_LF chr(13) + chr(10)

***************
FUNCTION MAIN()
***************
   if !InternetOK()
      Alert("Conexao com a internet falhou !")
   else
      Alert("Conexao OK")
   endif
   //
   // Abertura das funcoes para WebService do xHarbour
   //
   try
      doc := CreateObject( "MSXML2.DOMDocument" )
   catch
      try
         doc := CreateObject( "MSXML2.DOMDocument" )
      catch
         Alert("Erro na criacao do objeto MSXML2.DOMDocument : " + Ole2TxtError())
         return NIL
      end
   end

   try
      http := CreateObject( "MSXML2.XMLHTTP" )
   catch
      try
         http := CreateObject( "MSXML2.XMLHTTP" )
      catch
         Alert("Erro na criacao do objeto MSXML2.XMLHTTP : " + Ole2TxtError())
      end
   end
   //
   // Criar o XML request
   //
   cXml := ""
   cXml += '<?xml version="1.0" encoding="utf-8"?>' + CR_LF
   cXml += '<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:tem="http://tempuri.org/">' + CR_LF
   cXml += '  <soapenv:Header/>' + CR_LF
   cXml += '  <soapenv:Body>' + CR_LF
   cXml += '    <tem:ValidarUsuario>' + CR_LF
   cXml += '      <tem:Email>SEU_EMAIL_AQUI</tem:Email>' + CR_LF
   cXml += '      <tem:Senha>SUA_SENHA_AQUI</tem:Senha>' + CR_LF
   cXml += '    </tem:ValidarUsuario>' + CR_LF
   cXml += '  </soapenv:Body> ' + CR_LF
   cXml += '</soapenv:Envelope>' + CR_LF

//
// ENDERECO DE HOMOLOGACAO
//   
   http:Open( "POST", "http://homologacao.anvisa.gov.br/sngpc/webservice/sngpc.asmx?WSDL HTTP/1.1", .F. )
   http:SetRequestHeader( "Content-Type"   , "text/xml;charset=UTF-8" )
   http:SetRequestHeader( "SOAPAction"     , "http://tempuri.org/ValidarUsuario" )
   http:SetRequestHeader( "Host"           , "homologacao.anvisa.gov.br" )

//
// ENDERECO DE PRODUCAO
//   
// http:Open( "POST", "http://sngpc.anvisa.gov.br/webservice/sngpc.asmx?WSDL HTTP/1.1", .F. )
// http:SetRequestHeader( "Content-Type"   , "text/xml;charset=UTF-8" )
// http:SetRequestHeader( "SOAPAction"     , "http://tempuri.org/ValidarUsuario" )
// http:SetRequestHeader( "Host"           , "sngpc.anvisa.gov.br" )

   Alert("Carrega o request...")
   doc:LoadXML( cXml )                // Carrega o request de string

   Alert("Envia o xml...")
   http:send( doc:xml )               // Envia o request

   Alert("Ler a resposta...")
   response  := http:responseText     // Recebe a resposta

   Alert("Apresentando a resposta")

   oXmlDoc := TXmlDocument():new()
   oXMlDoc:read( response )

   oXmlNode := oXmlDoc:findFirst( "ValidarUsuarioResult" )
   Alert(oXmlNode:cName + " = " + oXmlNode:cData )

RETURN NIL

*********************
FUNCTION InternetOK()
*********************
   local aHosts, cName, cAddress := "www.google.com.br"
   InetInit()
   aHosts := InetGetHosts( cAddress )
   if aHosts == NIL .or. len(aHosts) == 0
      InetCleanup()
      return .F.
   endif
   InetCleanup()
RETURN .T.

Enviando arquivo xml para ANVISA

2011-04-25T09:11:00.000-07:00

Consegui terminar os webservices oficiais para o SNGPC da ANVISA.

O que deu mais trabalho foi o envio de arquivo. Pela descrição do serviço, precisariamos passar o <email>, <senha>, <arquivo> e <hash> desse arquivo como parametros. Dito assim ( e também pelo dá pra entender pelo manual do SNGPC ) o parametro <arquivo> deveria ser o path completo do arquivo. Mas não conseguia fazer funcionar. Já partindo pra apelação, fazendo todo tipo de teste, inclui todo o conteúdo do arquivo dentro do parametro <arquivo>. Deu erro, mas um erro diferente. Pesquisei um pouco mais e descobri que não deveria passar o arquivo com os caracteres '<' e '>', devendo substituir por '<' e '>'. Pronto ! Arquivo transferido, hash confirmado, tudo OK !

Só falta agora ler o inventário inicial da ANVISA pra terminar essa comunicação com o SNGPC. Dá até pra gerar uma classe, lib, dll ou até liberar os fontes mesmo pra quem quiser alterar ou entender mais o funcionamento do objeto XMLHTTPRequest.

Consumindo webservices

2011-04-23T13:25:00.000-07:00

Consegui finalmente consumir meu primeiro webservice com o xHarbour 1.0.0.

Usando o schema do SNGPC, validei o email/senha do usuário no SNGPC, verifiquei o status de um arquivo XML enviado e estou finalizando a transferencia de arquivo ( ainda não tá funcionando. A mensagem não é muito esclarecedora e o manual do SNGPC não ajuda em nada, mas tá quase pronto ).

Pra validar o schema SNGPC usei a versão free do SoapUI.

Ler inventario da ANVISA para o SNGPC

2011-04-21T11:29:00.000-07:00

Já vi em diversos softwares comerciais a importação do inventário da ANVISA no SNGPC. Não consta da definição do WSDL a operação de importação, então enviei um email para a equipe técnica da ANVISA perguntando como fazer.

Nada feito. Eles sabem como esses softwares processam as requisições, mas como não é um procedimento oficial, não podem descrever.
Vamos pesquisar !
Baixei o fiddler2, e comecei a testar os requests do browser com a página do SNGPC e as respostas do servidor.Acho que dá pra fazer tudo com o objeto XMLHTTPRequest. Só fico em dúvida pois uso ainda a versão 1.0.0 do xHarbour. Talvez seja hora de migrar definitivamente para o Harbour, principalmente agora com o suporte ao JSON, muito mais simples de trabalhar que o XML.

Início

2011-04-20T05:05:00.000-07:00

O objetivo é explorar as possibilidades do (x)Harbour. Estou cada vez mais convencido que dá pra fazer tudo : fazer aplicações web, ler conteúdo de redes sociais, criar interface para o twitter. É isso que pretendo fazer aqui, pra essas ideias nao ficarem em um canto qualquer dos meus hds e que mais pessoas usem essa fantástica ferramenta.